Contoh Sederhana Bekerja Dengan TabStrip - VB6

Bekerja dengan objek TabStrip dalam pengkodean VB6, maka tidak akan terlepas dari yang dinamakan Container. Diantara container yang banyak digunakan untuk keperluan ini adalah PictureBox. TabStrip berbeda dengan SSTab, TabStrip memerlukan tambahan kode untuk menampilkan objek-objek yang berada di bawah tab-nya.

Berikut merupakan contoh sederhana bagaimana bekerja dengan TabStrip. TabStrip yang digunakan dalam contoh adalah TabStrip yang berada pada komponen COMCTL32.OCX. Dengan mempergunakan COMCTL32.OCX maka tampilannya dapat mengikuti style window yang ada. Karena di dalam pengkodeannya akan banyak melakukan resize terhadap beberapa objek, cobalah untuk mempertimbangkan posting saya sebelumnya di sini.

Gambar: Tampilan tabstrip yang berada di bawah tabstrip lagi.

Download: Source Code VB6 - Contoh sederhana menggunakan TabStrip.

READ MORE - Contoh Sederhana Bekerja Dengan TabStrip - VB6

VB6 Code - Menambah Internet Explorer Pada Saat Runtime

Contoh kode VB6 sederhana untuk dikembangkan mengenai cara menambah objek internet explorer pada saat runtime.

Option Explicit

Private IE As VBControlExtender

Private Sub Form_Load()
    On Error GoTo IEMissing
    Set IE = Form1.Controls.Add("Shell.Explorer", "wcIE")
    IE.Visible = True
    If Not IE Is Nothing Then
        IE.object.silent = True
        IE.object.Navigate "http://khoiriyyah.blogspot.com"
    End If
IEMissing:

End Sub

Private Sub Form_Resize()
    If Not IE Is Nothing Then
        IE.Move 0, 0, Me.ScaleWidth, Me.ScaleHeight
    End If
End Sub

READ MORE - VB6 Code - Menambah Internet Explorer Pada Saat Runtime

VB Fungsi API - Memilih Seluruh Item ListBox

Contoh fungsi API untuk memilih (select all/deselect all) item pada ListBox.

Option Explicit

Private Declare Function SendMessage Lib "user32" Alias "SendMessageA" (ByVal hwnd As Long, ByVal wMsg As Long, ByVal wParam As Long, lParam As Any) As Long
Const LB_SETSEL = &H185

Private Sub Command1_Click()
    If List1.SelCount Then
        SendMessage List1.hwnd, LB_SETSEL, False, ByVal True
    End If
End Sub

Private Sub Command2_Click()
    SendMessage List1.hwnd, LB_SETSEL, True, ByVal True
End Sub

Private Sub Form_Load()
    'populate listbox
    Dim i As Long
    Me.Show
    List1.Visible = False
    Me.Refresh
    For i = 1 To 10000
        List1.AddItem i
    Next
    List1.Visible = True
End Sub

READ MORE - VB Fungsi API - Memilih Seluruh Item ListBox

VB6 Code - AutoFit TextBox.Text Caranya?

Yang dimaksud dengan AutoFit TextBox.Text disini adalah menyesuaikan ukuran huruf yang terdapat dalam objek TextBox agar sesuai dengan lebar textbox. Perhatikan gambar di bawah ini:

Pada mulanya text melebihi lebar textbox

menjadi:

Sekarang text sesuai dengan lebar textbox

Pada gambar di atas objek TextBox-nya lebih dari satu, sehingga prosedurnya harus dipanggil satu persatu menggunakan kode di bawah ini:

Option Explicit 
 '----------------------------------------------------------------------- 
'http://khoiriyyah.blogspot.com 
'By Asep Hibban Ibnu Surur) 
'----------------------------------------------------------------------- 
 
Private Sub Command1_Click() 
    Dim ctl As Object 
    For Each ctl In Me.Controls 
        If TypeName(ctl) = "TextBox" Then 
            AutoFitTextBox ctl 
        End If 
    Next 
End Sub 

Selengkapnya bisa Anda download pada link di bawah ini:

Download Project

READ MORE - VB6 Code - AutoFit TextBox.Text Caranya?

VB6 Code - Membuat Label Yang Berkedip-kedip

Bagaimana cara membuat label yang berkedip-kedip, simak kodenya di bawah ini:

Private Sub Form_Load()
   Label1.Caption = "http://4basic-vb.blogspot.com"
   Timer1.Interval = 300
End Sub

Private Sub Timer1_Timer()
   Label1.Visible = Not Label1.Visible
End Sub

READ MORE - VB6 Code - Membuat Label Yang Berkedip-kedip

VB6 Code - Memilih Item Listbox Secara Otomatis

Bagaimana cara memilih item yang terdapat pada ListBox secara otomatis pada saat mouse berada di atasnya menggunakan kode Visual Basic 6?

Option Explicit

Private Declare Function ClientToScreen Lib "user32" (ByVal hwnd As Long, lpPoint As POINTAPI) As Long
Private Declare Function LBItemFromPt Lib "COMCTL32.DLL" (ByVal hLB As Long, ByVal ptX As Long, ByVal ptY As Long, ByVal bAutoScroll As Long) As Long
Private Declare Function SendMessage Lib "user32" Alias "SendMessageA" (ByVal hwnd As Long, ByVal wMsg As Long, ByVal wParam As Long, lParam As Long) As Long

Private Const LB_SETCURSEL = &H186
Private Const LB_GETCURSEL = &H188

Private Type POINTAPI
    X As Long
    Y As Long
End Type

Private Sub HightLightListBox(ByVal hwndLB As Long, ByVal X As Single, ByVal Y As Single)

    Dim IndexItem As Long
    Dim Point As POINTAPI
    
    Point.X = X \ Screen.TwipsPerPixelX
    Point.Y = Y \ Screen.TwipsPerPixelY
    
    Call  ClientToScreen(hwndLB, Point)
    
    IndexItem = LBItemFromPt(hwndLB, Point.X, Point.Y, False)

    If IndexItem <> SendMessage(hwndLB, LB_GETCURSEL, 0, 0) Then
        Call SendMessage(hwndLB, LB_SETCURSEL, IndexItem, 0)
    End If

End Sub

READ MORE - VB6 Code - Memilih Item Listbox Secara Otomatis

VB6 Code - Horizontal Scrollbar Pada Listbox

Di bawah ini merupakan procedure VB6 untuk menambah ScrollBar pada objek ListBox. Seperti yang kita ketahui, ListBox tidak memiliki properties horizontal scroll bar akan tetapi dengan memanggil beberapa fungsi API hal tersebut mungkin untuk dilakukan.

Option Explicit

Private Declare Function SendMessageByNum Lib "user32" Alias "SendMessageA" (ByVal hwnd As Long, ByVal wMsg As Long, ByVal wParam As Long, ByVal lParam As Long) As Long
Private Const LB_SETHORIZONTALEXTENT = &H194

Public Sub AddHSBToListBox(sText As String, lst As ListBox)
    Static x As Long
    lst.AddItem sText
    If x < TextWidth(sText & "  ") Then
        x = TextWidth(sText & "  ")
    End If
    If ScaleMode = vbTwips Then
        x = x / Screen.TwipsPerPixelX
        SendMessageByNum lst.hwnd, LB_SETHORIZONTALEXTENT, x, 0
    End If
End Sub

Contoh penggunaan menambah horizontal scrollbar pada listbox

Private Sub  Command1_Click()
    Dim sText As String
    sText = ("This is a sample of long text, if the text longer than listbox, it will be create horizontal scrollbar automatically")
    AddHSBToListBox sText, List1
End Sub

READ MORE - VB6 Code - Horizontal Scrollbar Pada Listbox

VB6 Code - Horizontal Scrollbar Pada Richtextbox

Di bawah ini merupakan kode VB6 mengenai cara menambah horizontal scrollbar pada objek richtextbox.

Option Explicit

Private Sub Form_Load()
    With RichTextBox1
        .Text = "Visual Basic :: Horizontal Scroll Position In A Richtextbox, you must set the scrollbar properties to 1 or 3"
        .RightMargin = RichTextBox1.Width + 600
    End With
End Sub

READ MORE - VB6 Code - Horizontal Scrollbar Pada Richtextbox

VB6 Code - Procedure Auto Drop Down Pada Combobox

Di bawah ini merupakan procedure VB6 yang digunakan untuk membuat auto drop down pada objek ComboBox standar. Maksudnya, drop down otomatis apabila mouse berada di atasnya tanpa harus mengkliknya terlebih dahulu.

Option Explicit

Private Declare Function SendMessage Lib "user32" Alias "SendMessageA" (ByVal hwnd As Long, ByVal wMsg As Long, ByVal wParam As Long, lParam As Long) As Long
Const CB_SHOWDROPDOWN = &H14F

Public Sub AutoDropDown(cmb As ComboBox)
    Call SendMessage(cmb.hwnd, CB_SHOWDROPDOWN, 1, ByVal 0&)
    If cmb.ListIndex = -1 Then cmb.ListIndex = 0
End Sub

Contoh penggunaan proceder auto drop down pada combobox

Private Sub Combo1_GotFocus()
    AutoDropDown Combo1
End Sub

Private Sub Form_Load()
    With Combo1
        .AddItem "asep hibban"
        .AddItem "fahmi nurul anwar"
        .AddItem "mohammad galbi"
        .AddItem "karim wafi"
    End With
End Sub

READ MORE - VB6 Code - Procedure Auto Drop Down Pada Combobox

VB6 Code - Mencari Dengan Cepat Pada Listbox (Fungsi Api)

Di bawah ini merupakan fungsi VB6 yang digunakan untuk mencari sebuah item yang terdapat dalam objek ListBox dengan cepat.

Option Explicit

Private Declare Function SendMessage Lib "User32" Alias "SendMessageA" (ByVal hWnd As Long, ByVal wMsg As Integer, ByVal wParam As Integer, lParam As Any) As Long
Private Const LB_FINDSTRING = &H18F

Public Function SearchInList(sText As String, lst As ListBox)
    On Error Resume Next
    lst.ListIndex = SendMessage(lst.hWnd, LB_FINDSTRING, -1, ByVal sText)
    lst.TopIndex = List1.ListIndex - 1
End Function

Contoh penggunaan mencari dengan cepat menggunakan fungsi API

Private Sub Form_Load()
    With List1
        .AddItem "Bandung"
        .AddItem "Jakarta"
        .AddItem "Garut"
        .AddItem "Surabaya"
        .AddItem "New York"
        .AddItem "Khoiriyyah"
    End With
End Sub

Private Sub Text1_Change()
    SearchInList  Text1.Text, List1
End Sub

READ MORE - VB6 Code - Mencari Dengan Cepat Pada Listbox (Fungsi Api)

VB6 Code - Animasi Ketikan Tanpa Flicker

Fungsi VB6 di bawah ini digunakan untuk animasi yang menyerupai text yang sedang di ketik. Animasinya sangat halus nyaris tanpa kedipan.

Option Explicit

Dim sAnimation As String

Private Sub Form_Load()
    sAnimation = "Asep Hibban : http://4basic-vb.blogspot.com"
End Sub

Private Sub Timer1_Timer()
    Dim sToAnimate As String
    Static iAnimation As Integer
    Dim c As Integer
    iAnimation = iAnimation + 1
    
    sToAnimate = Mid(sAnimation, 1, iAnimation)
    With Picture1
        .Cls
        .CurrentX = 25
        .CurrentY = 100
        Picture1.Print sToAnimate
    End With
    If iAnimation >= Len(sAnimation) Then
      iAnimation = 0
    End If
End Sub

READ MORE - VB6 Code - Animasi Ketikan Tanpa Flicker

VB6 Code - Menjadikan Input Textbox Kapital

Di bawah ini merupakan kode VB6 untuk menjadikan text yang terdapat pada textbox menjadi kapital. Kode yang ditrigger pada saat penekanan tombol.

Option Explicit

'This one line code makes the contents of text box in capital. As you keep in typing it. Just copy this code keypress 
Private Sub Text1_KeyPress(KeyAscii As Integer)
    KeyAscii = Asc(UCase(Chr(KeyAscii)))
End Sub

READ MORE - VB6 Code - Menjadikan Input Textbox Kapital

VB6 Code - Memperoleh Jumlah Baris TextBox

Di bawah ini merupakan fungsi VB6 untuk memperoleh/mengetahui jumlah jajaran dalam sebuah textboxt. Fungsi tersebut menggunakan fungsi API SendMessageLong.

Option Explicit

Private Declare Function SendMessageLong Lib "user32" Alias "SendMessageA" (ByVal hwnd As Long, ByVal wMsg As Long, ByVal wParam As Long, ByVal lParam As Long) As Long
Private Const EM_GETLINECOUNT = &HBA

Public Function GetLineCount(Txt As TextBox)
    Dim lngLineCount As Long
    On Error Resume Next
    lngLineCount = SendMessageLong(Txt.hwnd, EM_GETLINECOUNT, 0&, 0&)
    GetLineCount = Format$(lngLineCount, "##,###")
End Function

Contoh penggunaan fungsi VB6 di atas:

Private Sub Command1_Click()
    MsgBox GetLineCount(Text1)
End Sub

READ MORE - VB6 Code - Memperoleh Jumlah Baris TextBox

VB6 Code - Menghapus Isi Textbox Dengan Cepat

Di bawah ini merupakan procedure VB6 untuk menghapus isi/text yang terdapat dalam textbox dengan cepat. Kami buat menjadi procedure agar mudah dalam penggunaan dan memiliki sifat mudah digunakan kembali (reusability)

Option Explicit

Public Sub ClearAllTextBoxes(frmClearMe As Form)
    Dim txt As Control
    For Each txt In frmClearMe
        If TypeOf txt Is TextBox Then txt.Text = ""
    Next
End Sub

Contoh penggunaan/pemanggilan procedure di atas

Private Sub Command1_Click()
    ClearAllTextBoxes Me
End Sub

READ MORE - VB6 Code - Menghapus Isi Textbox Dengan Cepat

VB Code - Mengubah Object LeftToRight Menjadi RighToLeft

Di bawah ini merupakan fungsi VB6 untuk mengubah objek yang tidak memiliki properties LeftToRight agar seolah-olah memiliki properties tersebut. Melalui akal-akalan fungsi API, hal tersebut mungkin untuk dilakukan.

Option Explicit

Private Declare Function SetWindowLong Lib "user32" Alias "SetWindowLongA" (ByVal hWnd As Long, ByVal nIndex As Long, ByVal dwNewLong As Long) As Long 'TreeView1 RightToLeft True

Private Const WS_EX_LAYOUTRTL = 4194304
Private Const GWL_EXSTYLE = -20

Public Sub ctlRightToLeft(ctl As Control)
    SetWindowLong ctl.hWnd, GWL_EXSTYLE, WS_EX_LAYOUTRTL
End Sub

Contoh penggunaan fungsi VB6 di atas:

Private Sub Command1_Click()
    ctlRightToLeft TreeView1
    TreeView1.Appearance = cc3D
    TreeView1.BorderStyle = ccFixedSingle
    TreeView1.Refresh
End Sub

Coba Anda ganti objeknya misalnya menggunakan Progress Bar, kemudian lihat apa yang terjadi?

READ MORE - VB Code - Mengubah Object LeftToRight Menjadi RighToLeft

VB6 Code - Membuat Efek Bayangan Pada Objek

Di bawah ini merupakan fungsi VB6 untuk membuat efek bayangan pada sebuah objek. Bagaimana implementasi dalam Visual Basic 6.0? bisa Anda simak kodenya di bawah ini:

Option Explicit

Public Function Shadow(frm As Form, ctl As Control, Optional shWidth = 3, Optional Color = vbGrayed)
    Dim oldWidth As Integer
    Dim oldScale As Integer
    
    With frm
        oldWidth = .DrawWidth
        oldScale = .ScaleMode
        .ScaleMode = 3
        .DrawWidth = 1
        frm.Line (ctl.Left + shWidth, ctl.Top + shWidth)-Step(ctl.Width - 1, ctl.Height - 1), Color, BF
        .DrawWidth = oldWidth
        .ScaleMode = oldScale
    End With
    
End Function

Contoh penggunaan fungsi membuat efek bayangan pada objek:

Private Sub Command1_Click()
    Shadow Me, Command1, 2, vbBlack
End Sub

Anda dapat menggunakannya pada objek secara bulk dengan menggunakan for...each.

READ MORE - VB6 Code - Membuat Efek Bayangan Pada Objek

VB6 Code - Vertical Scrollbar Textbox Pada Saat Runtime

Di bawah ini merupakan fungsi VB6 untuk menampilkan Vertical ScrollBar pada TextBox.

Option Explicit

Private Declare Function ShowScrollBar Lib "user32" (ByVal hwnd As Long, ByVal wBar As Long, ByVal bShow As Long) As Long

Public Function ShowScroll(obj As Control, bShow As Boolean)
    ShowScrollBar obj.hwnd, 1, bShow
    obj.Refresh
End Function

Contoh penggunaan kode VB6 di atas:

Public Sub Command1_Click()
    ShowScroll Text1, True
End Sub

READ MORE - VB6 Code - Vertical Scrollbar Textbox Pada Saat Runtime

VB Code - Mengisi Seluruh Fonts Ke Dalam Listbox

Di bawah ini merupakan fungsi VB6 untuk mengisi seluruh fonts yang ada dalam komputer Anda ke dalam objek ListBox pada dasarnya Anda dapat menggunakan objek selain ListBox seperti ListView, TreeView, dll.

Public Function LoadAllFonts(lst As Control)
    Dim i As Integer
    For i = 1 To 1000
        If Screen.Fonts(i) = "" Then Exit For
        lst.AddItem Screen.Fonts(i)
    Next i
End Function

Contoh penggunaan fungsi VB6 di atas:

Private Sub Form_Load()
    LoadAllFonts List1
End Sub

READ MORE - VB Code - Mengisi Seluruh Fonts Ke Dalam Listbox

VB6 Code - Input Textbox Hanya Untuk Numeric

Artikel ini diberi judul input textbox hanya untuk numeric, maksudnya ialah sebuah TextBox hanya dapat diisi dengan angka saja. Kodenya kami buat menjadi sebuah fungsi agar lebih mudah dalam penggunaan serta memiliki sifat dapat digunakan kembali (reusable). Adapun kode yang dimaksud:

Option Explicit

Private Sub OnlyNumeric(KeyAscii As Integer)

  Select Case KeyAscii
      Case 48 To 57                        ' numeric
      Case 8                               ' backspace
      Case Else: KeyAscii = 0
  End Select

End Sub

Cara penggunaan Fungsi TextBox hanya untuk numerik

Private Sub Text1_KeyPress(KeyAscii As Integer)
  OnlyNumeric KeyAscii
End Sub

Posted by Mesin Posting 1.0 Created by http://khoiriyyah.blogspot.com

READ MORE - VB6 Code - Input Textbox Hanya Untuk Numeric

VB6 Code - Fungsi Untuk Mengisi ListBox Dengan Seluruh File

Di bawah ini merupakan fungsi VB6 untuk mengisi Listbox dengan seluruh file, maksudnya (karena judul tersebut kurang lengkap) fungsi untuk mengisi ListBox dengan file-file dari sebuah directory yang telah ditentukan.

Fungsi untuk mengisi ListBox dengan seluruh file:

Function LoadFilesToList(FileName As String, lst As ListBox, Optional Attrib As VbFileAttribute)
    Dim sNextFile As String
    sNextFile = Dir$(FileName, Attrib)
    While sNextFile <> ""
        If sNextFile <> "." And sNextFile <> ".." Then
            lst.AddItem sNextFile
        End If
        sNextFile = Dir$
    Wend
End Function

Contoh Penggunaan fungsi untuk mengisi ListBox dengan seluruh file:

Private Sub Command2_Click()
     LoadFilesToList "C:\Windows\System32\*", List1, vbArchive + _
     vbDirectory + vbSystem
    'mengenai vbArchive + vbDirectory + vbSystem optional, boleh _
    diisi atau tidak tergantung kebutuhan
End Sub

READ MORE - VB6 Code - Fungsi Untuk Mengisi ListBox Dengan Seluruh File